エクセル技道場>条件付き書式

エクセル技道場 HOME
エクセルの技 目次
シート
関数
名前定義
ツールバー
セル選択
ファイル
条件付き書式
書式設定
編集
印刷
入力規則
マクロ
グラフ
ピボットテーブル
エクセル・ショートカット
エクセル関数語源リスト
エクセル関数引数リスト
  1. 特定の文字列が入っているセルに色をつける
  2. 特定の文字列が入っているセルに色をつける2
  3. 土日に色をつける
  4. 複数のセルの中に特定の数字があったら色をつける
  5. 複数のセルの中に特定の数字がなかったら色をつける
  6. 複数のセルの中に特定の数字がなかったら色をつける2
  7. 複数のセルの中に特定の数字がなかったら色をつける3
  8. 両隣の文字列によって真ん中のセルの色を変える
  9. 複数条件
  10. 別のセルを参照して条件付き書式を設定
  11. 誕生日の3日前から日付を赤に
  12. 他のシートを参照
  13. アドイン関数を使って条件付き書式設定
  14. 偶数行のセルに色をつける
  15. 選択範囲内で偶数行のセルに色をつける
  16. 選択範囲内でn行おきにセルに色をつける
  17. セルに市松模様で色をつける
  18. セルにn行列おきに市松模様で色をつける
  19. 特定セルと同じセルに色をつける
  20. 空白セルがあればその行全体に色をつける
  21. 別シートにある文字列との重複チェック
  22. 部分一致
  23. 部分一致2
  24. 部分一致3
  25. 部分一致4
  26. 部分一致5
  27. 直前に入力した行全体に色をつける
  28. 土日祝日に色をつける
  29. ロックされていないセルに色をつける
  30. 本日の日の列に色をつける
  31. 同じ列の値がかわったら罫線を引く
  32. 特定範囲のデータを見えなくする
  33. 最大値のセルに色をつける
  34. 各列で最大値のセルに色を付ける
  35. 上位3位までのセルに色を付ける
  36. BINGOの発生数字に色を付ける
  37. 数式の入っているセルに色を付ける

特定の文字列が入っているセルに色をつける

【問題】
 B2:B6に以下のように性別が入力されています。







 女と入力されているセルの色を黄色にするにはどうしたら良いでしょうか?

【回答】
1.B2:B6を選択
2.メニュー[書式]-[条件付き書式]
3.[セルの値が]になっていることを確認し、右のボックスを[次の値に等しい]に
4.[次の値に等しい]の右のボックスに 女 と入力
5.[書式]ボタンをクリック
6.[パターン]タブで[黄色]をクリック
7.Enter
8.[OK]ボタンをクリック

【解説】
 上記手順の1.で列番号Bを押して列全体に条件付き書式設定を行うこともできます。サンプルファイルはB列全体に条件付き書式設定をしています。

 上記手順の4.で 女 と入力していますが、上記手順終了後にメニュー[書式]-[条件付き書式]を見てみると、="女" に自動的になっています。

 条件付き書式は、Excel97 から追加された機能です。

特定の文字列が入っているセルに色をつける2

【問題】
 A2:B6に以下のように名前と性別が入力されています。

佐藤 男
田中 女
鈴木 男
小川 男
山田 女

 女と入力されていたら、名前と性別の両方のセルが黄色になるようにするにはどうしたら良いでしょうか?

【回答】
1.A2をクリックしてマウスをドラッグしてA2:B6を選択
→セルA2がアクティブでA2:B6を選択
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =$B2="女" と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄色]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。

 条件付き書式設定をしている時のアクティブセルと、[数式]に入力するセル参照の対応関係が意図しているものとちゃんと合っているかというのがポイントになります。

 =$B2="女" のように列だけを絶対参照しています。こうすることによって、セルA2においても、セルB2においても セルB2が 女 かどうかという条件になるのです。

 列番号Aをクリックして列番号Bまでドラッグすることで、列A:Bを選択して、列全体に条件付き書式を設定することもできます。その場合にはセルA1がアクティブセルなので、=$B1="女" とします。
 サンプルファイルは列全体に条件付き書式を設定しています。

土日に色をつける

【問題】
 A列に以下のように日付が入っています。

2000/10/1
2000/10/2
2000/10/3
2000/10/4
2000/10/5
2000/10/6
2000/10/7
2000/10/8
2000/10/9
2000/10/10

 土日については、日付の色を赤にするには、どうすれば良いでしょうか?

【回答】
1.列番号Aをクリック
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =WEEKDAY(A1,2)>=6 と入力
4.[書式]ボタンをクリック
5.[フォント]タブの[色]で[赤]をクリック
6.[OK]ボタンをクリック
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 WEEKDAY関数は、日付(シリアル値)から曜日に対応する値を返します。
 WEEKDAY(シリアル値, 種類)という引数をとります。種類によって曜日に対応する値が異なります。
 種類は以下の3種類があります。種類を省略すると1になります。

 1: 1 (日曜) 〜 7 (土曜)
 2: 1 (月曜) 〜 7 (日曜)
 3: 0 (月曜) 〜 6 (日曜)

 この式では、種類を2にしています。
 =WEEKDAY(A1,2) が6以上、すなわち6(土曜)、7(日曜)であれば、
=WEEKDAY(A1,2)>=6 はTRUEを返すわけです。

複数のセルの中に特定の数字があったら色をつける

【問題】
 A1:F1のどれかに 1 が入力されたら、A1:F1全体に色をつけるようにするにはどうしたら良いでしょうか?

【回答】
1.A1をクリックしてマウスをドラッグしてA1:F1を選択
→セルA1がアクティブでA1:F1を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =COUNTIF($A1:$F1,1)>=1 と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。

=COUNTIF($A1:$F1,1)>=1
でA1:F1内に1が一つでもあれば、TRUEが返ります。

=OR($A1:$F1=1)
でも同じ結果になります。以下は、=OR($A1:$F1=1)の解説です。

 A1:F1に例えば、6,5,4,3,2,1 が入っているとします。

=$A1:$F1=1 の返り値は {FALSE,FALSE,FALSE,FALSE,FALSE,TRUE} になります。

 OR関数はいずれかの引数が TRUE のとき、TRUE を返します。従って、
=OR($A1:$F1=1) の返り値はTRUEになり、条件付き書式で設定した書式が適用されます。

 サンプルファイルでは、A:F列全体に条件付き書式を設定しています。同じ行のA:F列内のセルに一つでも1が入力されるとその行のA:Fに色が付くようになっています。

 条件付き書式は、Excel97 から追加された機能です。

複数のセルの中に特定の数字がなかったら色をつける

【問題】
 A1:F1のどれにも 1 がなかったら、A1:F1全体に色をつけるようにするにはどう
したら良いでしょうか?

【回答】
1.A1をクリックしてマウスをドラッグしてA1:F1を選択
→セルA1がアクティブでA1:F1を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =COUNTIF($A1:$F1,1)=0 と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。

=COUNTIF($A1:$F1,1)=0
でA1:F1内に1が一つでもあれば、FALSEが返ります。

=NOT(OR($A1:$F1=1))
でも同じ結果になります。以下は、=NOT(OR($A1:$F1=1))の解説です。

 A1:F1に例えば、6,5,4,3,2,1 が入っているとします。

=$A1:$F1=1 の返り値は {FALSE,FALSE,FALSE,FALSE,FALSE,TRUE} になります。

 OR関数はいずれかの引数が TRUE のとき、TRUE を返します。従って、
=OR($A1:$F1=1) の返り値はTRUEになります。

 NOT関数は引数が TRUE のとき FALSE を、FALSE のとき TRUE を返します。従って、
=NOT(OR($A1:$F1=1)) の返り値はFALSEになり、条件付き書式で設定した書式は適用されません。

 サンプルファイルでは、A1:F30に条件付き書式を設定しています。同じ行のA:F列内のセルに一つでも1が入力されるとその行のA:Fの色が消えます

複数のセルの中に特定の数字がなかったら色をつける2

【問題】
 A1:F1のどれにも 2 または 3 が入力されていなかったら、A1:F1全体に色をつけるようにするにはどうしたら良いでしょうか?

【回答】
1.A1をクリックしてマウスをドラッグしてA1:F1を選択
→セルA1がアクティブでA1:F1を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに
=(COUNTIF($A1:$F1,2)+COUNTIF($A1:$F1,3))=0
と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
=(COUNTIF($A1:$F1,2)+COUNTIF($A1:$F1,3))=0
でA1:F1内に2または3が一つでもあれば、FALSEが返ります。

 A1:F1に例えば、6,5,4,3,2,1 が入っているとします。

=COUNTIF($A1:$F1,2) は1を、=COUNTIF($A1:$F1,3) も1を返し、=(COUNTIF($A1:$F1,2)+COUNTIF($A1:$F1,3)) は2となります。
 従って、=(COUNTIF($A1:$F1,2)+COUNTIF($A1:$F1,3))=0 はFALSEを返し、条件付き書式で設定した書式は適用されません。

=NOT(OR($A1:$F1=2,$A1:$F1=3))
でも同じ結果になります。

 サンプルファイルでは、A1:F30に条件付き書式を設定しています。同じ行のA:F列内のセルに一つでも2または3が入力されるとその行のA:Fの色が消えます

複数のセルの中に特定の数字がなかったら色をつける3

【問題】
 A1:F1のどれかに2と3の両方が入力されていなかったら、A1:F1全体に色をつけるようにするにはどうしたら良いでしょうか?

【回答】

1.A1をクリックしてマウスをドラッグしてA1:F1を選択
→セルA1がアクティブでA1:F1を選択している状態

2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに

=NOT(AND(OR($A1:$F1=2),OR($A1:$F1=3)))

と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。

 A1:F1に例えば、6,5,4,3,2,1 が入っているとします。

=$A1:$F1=2
の返り値は、{FALSE,FALSE,FALSE,FALSE,TRUE,FALSE} になります。

従って、
=OR($A1:$F1=2)
の返り値は TRUE になります。

=$A1:$F1=3
の返り値は、{FALSE,FALSE,FALSE,TRUE,FALSE,FALSE} になります。

従って、
=OR($A1:$F1=3)
の返り値は TRUE になります。

 AND関数はすべての引数が TRUE のとき、TRUE を返します。
=AND(OR($A1:$F1=2),OR($A1:$F1=3))
は、=AND(TRUE,TRUE) ということになり、TRUE が返ります。

=NOT(AND(OR($A1:$F1=2),OR($A1:$F1=3)))
は、=NOT(TRUE) ということになり、FALSEが返し、条件付き書式で設定した書式は適用されません。

=(COUNTIF($A1:$F1,2)*COUNTIF($A1:$F1,3))=0
でも同じ結果になります。

 サンプルファイルでは、A1:F30に条件付き書式を設定しています。同じ行のA:F列内に2と3の両方が入力されるとその行のA:Fに付いていた色が消えるようになっています。

両隣の文字列によって真ん中のセルの色を変える

【問題】
 両隣の文字列を判断して、真ん中のセルの色を変える事はできるでしょうか?
 例えば、A1:C6に以下が入力されているとします。

勤務 山田 A棟
出張 佐藤 B棟
勤務 田中 C棟
出張 鈴木 A棟
出張 松井 B棟
出張 木村 C棟

 つまり、
 勤務とA棟で挟まれたデータを赤で、
 出張とB棟で挟まれたデータを黄で塗りたいのです。

【回答】
1.セルB1をクリック
2.ドラッグしてB1:B6を選択
→アクティブセルがセルB1でB1:B6を選択している状態
3.メニュー[書式]−[条件付き書式]
4.「数式が」を選択
5.右のボックスに =AND(A1="勤務",C1="A棟") と入力
6.[書式]ボタンをクリック
7.[パターン]タブで[赤]をクリック
8.Enter
9.[追加]ボタンをクリック
10.[条件2]のところで「数式が」を選択
11.右のボックスに =AND(A1="出張",C1="B棟") と入力
12.[書式]ボタンをクリック
13.[パターン]タブで[黄]をクリック
14.Enter
15.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。
 条件付き書式設定は、条件を三つまで指定できます。

 設定した条件付き書式を削除するには以下の手順です。

1.Ctrl+G (メニュー[編集]-[ジャンプ])
2.[セル選択]ボタンをクリック
3.[条件付き書式]にチェック
4.Enter
→これで条件付き書式が設定されたセル範囲が選択されます。
5.メニュー[書式]-[条件付き書式]
6.[削除]ボタンをクリック
7.削除する条件の横にチェック
8.Enter
9.[OK]ボタンをクリック

 シートに別の条件付き書式設定がある場合には、上記3のところで、[条件付き書式]にチェックして、[同じ入力規則]にチェックを入れます。

複数条件

【問題】
 以下のような表がA1:C5にあります。

組織 部課 コード
1000 001 510
1000 001 530
1000 003 510
1000 003 530

 上のセルと同じ場合は文字を消す(フォントを白に)、
 下のセルと違う場合は罫線(下線)を引く、にはどうしたら良いでしょうか?

組織 部課 コード
1000 001 510
    530
   003 510
    530

【回答】
1.セルA3をクリックしてからドラッグしてA3:C6を選択
→セルA3がアクティブでA3:C5を選択している状態に

2.メニュー[書式]-[条件付き書式]
→[条件付き書式の設定]ダイアログボックスを表示

3.[条件1]で[セルの値が]、[次の値に等しい]で、右のボックスに =A2 と入力

4.[書式]ボタンをクリック
→[セルの書式設定]ダイアログボックスを表示

5.[フォント]タブの[色]で[白]をクリック

6.[OK]ボタンをクリック
→[条件付き書式の設定]ダイアログボックスを表示

7.[追加]ボタンをクリック

8.[条件2]で[セルの値が]、[次の値に等しくない]で、右のボックスに =A2 と入


9.[書式]ボタンをクリック
→[セルの書式設定]ダイアログボックスを表示

10.[罫線]タブで[上罫線]をクリック

11.[OK]ボタンをクリック
→[条件付き書式の設定]ダイアログボックスを表示

12.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。
 条件付き書式設定は、条件を三つまで指定できます。
 複数の条件を指定すると、最初に満たされた条件の書式だけが適用されます。

 上のセルと同じ場合は文字を消す(フォントを白に)、
 下のセルと違う場合は罫線(下線)を引く、なので、

 セルA2:C5を選択して、
[条件1]を[次の値に等しい]、 =A2 で、フォントを[白]に、
[条件2]を[次の値に等しくない]、 =A3 で、[下罫線]、
とするのが自然なように見えますが、すると以下のように失敗します。

組織 部課 コード
1000 001 510
    530
  003 510
    530

 サンプルファイルでは、A3:C30に条件付き書式を設定しています。

別のセルを参照して条件付き書式を設定

【問題】

数量 単価 金額
1 200 200
2 300 600

 A1:C3に上記のような表があるとします。金額には数量×単価の計算式が入力されています。
 数量が1のときには単価の入っているセルのフォントを白にして表示させないようにするにはどうしたら良いでしょうか?

【回答】
1.列番号Bをクリック
→セルB1がアクティブでB列が選択されている状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =A1=1 と入力
4.[書式]ボタンをクリック
5.[フォント]タブの[色]で[白]をクリック
6.[OK]ボタンをクリック
7.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。

 条件付き書式設定をしている時のアクティブセルと、[数式]に入力するセル参照の対応関係が意図しているものとちゃんと合っているかというのがポイントになります。

誕生日の3日前から日付を赤に

【問題】
 A列に日付が入っています。
 誕生日の三日前から誕生日当日までの日付を赤にするにはどうすれば良いでしょうか?

【回答】
1.列番号Aをクリック
→セルA1がアクティブでA列が選択されている状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに以下の数式を入力

=DATEDIF(TODAY(),DATE(YEAR(TODAY())+400,MONTH(A1),DAY(A1)),"YD")<=3

4.[書式]ボタンをクリック
5.[フォント]タブの[色]で[赤]をクリック
6.[OK]ボタンをクリック
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 閏日関係をうまく計算させるためにちょっと複雑な式になっています。
 DATEDIF関数は[開始日]が閏年か平年かで違った値を返す、DATEDIF関数において[開始日]は[終了日]より前の日付でなければならない、の二つの条件を勘案し、[終了日]を"年が今日の年の400年後で月日は生年月日"というふうにしています。

 DATEDIF関数は、指定された期間内の日数、月数、または年数を返します。
 DATEDIF(開始日,終了日,単位)という引数をとります。

 [開始日]は[終了日]より前の日付でなければいけません。[終了日]が[開始日]より前の日付の場合にはエラーとなります。

[単位]で戻り値の種類を指定します。
"Y" 期間内の満年数
"M" 期間内の満月数
"D" 期間内の満日数
"MD" 1ヶ月未満の日数
"YM" 1年未満の月数
"YD" 1年未満の日数

 DATEDIF関数は、Lotus 1-2-3 関数との互換性を保つために用意されています。[関数ウィザード] の「関数名一覧」には含まれていません。

 DATEDIF関数は、[開始日]が閏年か平年かで違った値を返します。

=DATEDIF("1998/2/1","1999/3/1","YD") は 28(平年−平年)
=DATEDIF("1999/2/1","2000/3/1","YD") は 28(平年−閏年)
=DATEDIF("2000/2/1","2001/3/1","YD") は 29(閏年−平年)
=DATEDIF("2000/2/1","2004/3/1","YD") は 29(閏年−閏年)

 以下のページもご参考になると思いますので、ご覧になってみてください。

[XL] うるう年を判定する方法

[XL2002]WEEKDAY関数で1900年3月1日より前の正しい曜日が返らない

[XL2000]DATEDIF関数が関数ウィザ-ドの関数名一覧に含まれない

[XL2002] 日数および時間計算に関するワークシート関数について

他のシートを参照

【問題】
 Sheet1のA1:A5に以下が入力されています。
1
2
3
4
5

 Sheet2のセルA1の値以上のセルを黄色にするにはどうすれば良いでしょうか?

【回答】
 まずは、名前定義です。

1.Sheet2のセルA1を選択
2.名前ボックス(数式バーの左横)をクリック
3.例えば 基準 と入力
4.Enterキーを押す

 続いて条件付き書式設定です。

1.Sheet1のA1:A5を選択
2.メニュー[書式]-[条件付き書式]
3.[セルの値が]で、右のボックスを[次の値以上]に
4.その右のボックスでF3キー (メニュー[挿入]-[名前]-[貼り付け])
5. 基準 をクリック
6.Enter
7.[書式]ボタンをクリック
8.[パターン]タブで[黄]をクリック
9.Enter
10.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 名前定義をしないで他のシートのセルへの参照を直接条件にしようとすると、「抽出条件 条件付き書式で、他のワークシートまたはブックへの参照は使用しません。」というエラーメッセージが出てしまい条件を設定することができません。

 名前定義することで他のシートのセルの値との比較等を条件にすることが可能になります。

 名前定義については、以下のページもご参考になさってください。

【エクセル技道場】−名前定義

アドイン関数を使って条件付き書式設定

【問題】
 A列に日付が入っています。
 今日の一ヶ月後の日付が入っているセルの色を黄色にするには、どうしたら良いでしょうか?
 EDATE関数と条件付き書式で実現します。

【回答】
 まずは、名前定義です。

1.Ctrl+F3 (メニュー[挿入]-[名前]-[定義])
2.[名前]に例えば 一ヶ月後 と入力
3.[参照範囲]に =EDATE(TODAY(),1) と入力
4.Enterキーを押す

 続いて条件付き書式設定です。

1.列番号Aをクリック
2.メニュー[書式]-[条件付き書式]
3.[セルの値が]で、右のボックスを[次の値に等しい]に
4.その右のボックスでF3キー (メニュー[挿入]-[名前]-[貼り付け])
5. 一ヵ月後 をクリック
6.Enter
7.[書式]ボタンをクリック
8.[パターン]タブで[黄]をクリック
9.Enter
10.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 EDATE関数を使うには、メニュー[ツール]-[アドイン]で[分析ツール]にチェックをしておく必要があります。

 名前定義をしないでEDATE関数のようなアドイン関数を使った数式を直接条件にしようとすると、「抽出条件 条件付き書式で、他のワークシートまたはブックへの参照は使用しません。」というエラーメッセージが出てしまい条件を設定することができません。
 名前定義することでアドイン関数を使った数式を条件にすることが可能になります。

 EDATE関数は、開始日から起算して、指定された月数だけ前または後の日付に対応するシリアル値を返します。
 EDATE(開始日, 月)という引数をとります。
 引数の 月 には、 開始日 から起算した月数を指定します。月 に正の数を指定すると、起算日より後の日付となり、負の数を指定すると、起算日より前の日付となります。

 名前定義については、以下のページもご参考になさってください。

エクセル技道場−名前定義

偶数行のセルに色をつける

【問題】
 A2:E20で偶数の行のセルに色をつけるにはどうしたら良いでしょうか?
 条件付き書式設定で実現します。

【回答】
1.セルA2をクリックしてドラッグしてA2:E20を選択
→アクティブセルはセルA2でA2:E20を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =MOD(ROW(),2)=0 と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 ROW関数は、引数として指定された範囲の行番号を返します。
 ROW(範囲)という引数をとります。
 範囲 を省略すると、ROW関数が入力されているセルの行番号が返されます。

 MOD関数は、数値を除数で割ったときの剰余を返します。戻り値は除数と同じ符号になります。
 MOD(数値, 除数)という引数をとります。
 この式の場合、除数は2です。2で割った余りが0ということは、2の倍数、すなわち偶数となります。

 奇数行のセルに色をつけるには、=MOD(ROW(),2)=1 とします。

選択範囲内で偶数行のセルに色をつける

【問題】
 選択範囲(A2:E20)内で偶数の行のセルに色をつけるにはどうしたら良いでしょうか?すなわち、選択範囲内で2行目であるA3:E3、4行目であるA5:E5・・・に色をつけたいのです。
 条件付き書式設定で実現します。

【回答】
1.セルA2をクリックしてドラッグしてA2:E20を選択
→アクティブセルはセルA2でA2:E20を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =MOD(ROWS(A$2:A2),2)=0 と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 ROW関数は行番号を返します。一方、ROWS関数は、セル範囲の行数を返します。
 =ROWS(A$2:A2) は1、=ROWS(A$2:A3) は2、=ROWS(A$2:A4) は3 といった感じです。

 MOD関数は、数値を除数で割ったときの剰余を返します。
 MOD(数値, 除数)という引数をとります。
 この式の場合、除数は2です。2で割った余りが0ということは、2の倍数、すなわち偶数となります。

 選択範囲内で奇数行のセルに色をつけるには、=MOD(ROWS(A$2:A2),2)=1 とします。

選択範囲内でn行おきにセルに色をつける

【問題】
 選択範囲(A2:E30)内で2行おきに条件付き書式設定でセルに色をつけるにはどうしたら良いでしょうか?
 すなわち、A2:E3、2行あけてA6:E7、また2行あけてA10:E11・・・といった感じで色をつけるにはどうしたら良いでしょうか?
 また、3行おき、4行おき、5行おきにセルに色をつけるにはどうしたら良いでしょうか?

【回答】
1.セルA2をクリックしてドラッグしてA2:E30を選択
→アクティブセルはセルA2でA2:E30を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =MOD(ROWS(A$2:A2)-1,4)<2 と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 上記は2行おきにセルに色をつける場合の手順です。
 3行おき、4行おき、5行おきにセルに色をつける場合には、上記手順の3.のところで以下の数式を入力します。

=MOD(ROWS(A$2:A2)-1,6)<3
=MOD(ROWS(A$2:A2)-1,8)<4
=MOD(ROWS(A$2:A2)-1,10)<5

=MOD(ROWS(A$2:A2)-1,行数×2)<行数 という法則があります。

 上記は、最初のn行分から色をつけていきます。次のn行分から色をつけていくには、
=MOD(ROWS(A$2:A2)-1,行数×2)>=行数 とします。
 2行おきだったら、
=MOD(ROWS(A$2:A2)-1,4)>=2
といった感じです。

セルに市松模様で色をつける

【問題】
 セルに市松模様で色をつけるにはどうしたら良いでしょうか?

■ ■ ■
 ■ ■
■ ■ ■
 ■ ■
■ ■ ■

 条件付き書式設定で実現します。

【回答】
1.全セルを選択
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =MOD(ROW()+COLUMN(),2) と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 ROW関数は、引数として指定された範囲の行番号を返します。
 ROW(範囲)という引数をとります。
 範囲 を省略すると、ROW関数が入力されているセルの行番号が返されます。

 COLUMN関数は、引数として指定された範囲の列番号を返します。
 COLUMN(範囲)という引数をとります。
 範囲 を省略すると、COLUMN関数が入力されているセルの列番号が返されます。

 MOD関数は、数値を除数で割ったときの剰余を返します。
 MOD(数値, 除数)という引数をとります。
 この式の場合、除数は2です。整数を2で割った余りは0か1の二つしかありません。

 セルA2の場合には、行番号は2、列番号は1、従って =ROW()+COLUMN() は3となります。
=MOD(3,2) すなわち、3を2で割った余りは1となり、1はTRUEと判断されるので、セルA2に色がつきます。

 セルA3の場合には、行番号は3、列番号は1、従って =ROW()+COLUMN() は4となります。
=MOD(4,2) すなわち、4を2で割った余りは0となり、0はFALSEと判断されるので、セルA3には色がつきません。

 つまり、行番号 + 列番号が奇数であればTRUEで色がつき、偶数であればFALSEで色がつかないようになってます。
 行番号 + 列番号が奇数のセルの一行下のセル及び一列右のセルは、行番号 + 列番号 + 1 なので、偶数となります。右下のセルは行番号 + 列番号 + 2 なので、奇数となります。

 色がつくパターンを逆にするには、上記3.で以下の数式にします。

=MOD(ROW()+COLUMN(),2)=0

セルにn行列おきに市松模様で色をつける

【問題】
 全セルに市松模様で2行列おきに色をつけるにはどうしたら良いでしょうか?

■■  ■■  ■■
■■  ■■  ■■
  ■■  ■■
  ■■  ■■
■■  ■■  ■■
■■  ■■  ■■
  ■■  ■■
  ■■  ■■

 また、3行列おき、4行列おき、行は2行おきで列は3列おきにセルに色をつけるにはどうしたら良いでしょうか?

 条件付き書式設定で実現します。

【回答】
1.全セルを選択
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに
=(MOD(ROW()-1,4)<2)=(MOD(COLUMN()-1,4)<2) と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 3行列おき、4行列おきにセルに色をつける場合には、上記手順の3.のところで以下の数式を入力します。

=(MOD(ROW()-1,6)<3)=(MOD(COLUMN()-1,6)<3)
=(MOD(ROW()-1,8)<4)=(MOD(COLUMN()-1,8)<4)

 行は2行おきで列は3列おきにセルに色をつける場合には、上記手順の3.のところで以下の数式を入力します。

=(MOD(ROW()-1,4)<2)=(MOD(COLUMN()-1,6)<3)

=(MOD(ROW()-1,行数×2)<行数)=(MOD(COLUMN()-1,列数×2)<列数) という法則が
あります。

 色がつくパターンを逆にするには、上記3.で以下の数式にします。
=(MOD(ROW()-1,4)<2)<>(MOD(COLUMN()-1,4)<2)
 つまり、
=(MOD(ROW()-1,行数×2)<行数)<>(MOD(COLUMN()-1,列数×2)<列数)
のようにします。

特定セルと同じセルに色をつける

【問題】
 A1:D3に以下が入力されています。

りんご なし かき りんご
みかん りんご みかん かき
なし かき りんご なし

 セルA1と同じ単語が入ったセルに色をつけるにはどうしたら良いでしょうか?

【回答】
1.A1をクリックしてマウスをドラッグしてA1:D3を選択
→セルA1がアクティブでA1:D3を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[セルの値が]で、右のボックスを[次の値に等しい]に、その右に =$A$1と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 A列と同じ単語が入ったセルに色をつけるには、上記3.で =$A1 と入力します。

空白セルがあればその行全体に色をつける

【問題】
 A1:F10に表があります、
 その行のどれかが空白であったら、その行全体に色をつけるにはどうしたら良いでしょうか?

【回答】
1.A1をクリックしてマウスをドラッグしてA1:F10を選択
→セルA1がアクティブでA1:F10を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =OR($A1:$F1="") と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 上記3.で =OR(ISBLANK($A1:$F1)) でも結構です。

別シートにある文字列との重複チェック

【問題】
 Sheet2のA1:A100に入力した文字列が、Sheet1のA1:B10の文字列と重複していたとき、Sheet2のそのセルに色をつけるにはどうしたら良いでしょうか?

【回答】
 まずは名前定義です。

1.Sheet1のA1:B10を選択
2.名前ボックスに LIST と入力
3.Enter

 Sheet2のA1:A100に条件付き書式を以下のように設定します。

1.Sheet2のセルA1をクリック、ドラッグしてA100まで選択
→セルA1がアクティブでA1:A100が選択された状態
2.メニュー[書式]-[条件付き書式]
3.左のボックスを 数式が に、右のボックスに =COUNTIF(LIST,A1) と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]を選択
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 名前定義をしないで他のシートのセルへの参照を直接条件にしようとすると、「抽出条件 条件付き書式で、他のワークシートまたはブックへの参照は使用しません。」というエラーメッセージが出てしまい条件を設定することができません。

 名前定義することで他のシートのセルの値との比較等を条件にすることが可能になります。

部分一致

【問題】
 A列に以下が入力してあります。



花水木
生け花
造花
花より団子
団子
花柄
柄物
花見

花盛り
酒盛り
花札と花束
お札
桜の花と花園と花屋
花屋と花屋

 花 という文字が含まれているセルに色をつけるにはどうしたら良いでしょうか?

 それから、
−先頭の一文字が 花 のセル
−末尾の一文字が 花 のセル
に色をつけるにはどうしたら良いでしょうか?
 
【回答】
1.列番号Aをクリック
→セルA1がアクティブでA列が選択された状態
2.メニュー[書式]-[条件付き書式]
3.左のボックスを 数式が に、右のボックスに =COUNTIF(A1,"*花*") と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]を選択
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 [セルの値が]、[次の値に等しい]で 花 とすると、花 と入力されたセルしか条件がTRUEになりません。

 ワイルドカード文字 * (アスタリスク)は、同じ位置にある任意の数の文字を意味します。

 先頭の一文字が 花 のセルに色をつけるには以下の数式です。
=COUNTIF(A1,"花*")
または
=LEFT(A1)="花"

 末尾の一文字が 花 のセルに色をつけるには以下の数式です。
=COUNTIF(A1,"*花")
または
=RIGHT(A1)="花"

部分一致2

【問題】
 A列に以下が入力してあります。



花水木
生け花
造花
花より団子
団子
花柄
柄物
花見

花盛り
酒盛り
花札と花束
お札
桜の花と花園と花屋
花屋と花屋

 花 という文字が含まれていないセルに色をつけるにはどうしたら良いでしょうか?

 それから、
−先頭の一文字が 花 ではないセル
−末尾の一文字が 花 ではないセル
に色をつけるにはどうしたら良いでしょうか?

 いずれも空白のセルに色はつけません。

【回答】
1.列番号Aをクリック
→セルA1がアクティブでA列が選択された状態
2.メニュー[書式]-[条件付き書式]
3.左のボックスを 数式が に、右のボックスに以下の数式を入力
=COUNTIF(A1,"*花*")+ISBLANK(A1)=0
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]を選択
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

=NOT(OR(COUNTIF(A1,"*花*"),ISBLANK(A1)))
でも同じ結果になります。

 ワイルドカード文字 * (アスタリスク)は、同じ位置にある任意の数の文字を意味します。

 先頭の一文字が 花 ではないセルに色をつけるには以下の数式です。
=COUNTIF(A1,"花*")+ISBLANK(A1)=0
または
=AND(LEFT(A1)<>"花",NOT(ISBLANK(A1)))

 末尾の一文字が 花 ではないセルに色をつけるには以下の数式です。
=COUNTIF(A1,"*花")+ISBLANK(A1)=0
または
=AND(RIGHT(A1)<>"花",NOT(ISBLANK(A1)))

部分一致3

【問題】
 A列に以下が入力してあります。



花水木
生け花
造花
花より団子
団子
花柄
柄物
花見

花盛り
酒盛り
花札と花束
お札
桜の花と花園と花屋
花屋と花屋

 花が二文字入っているセル(e.g. 花札と花束)に色をつけるにはどうしたら良いでしょうか?
 また花が二文字以上入っているセルに色をつけるにはどうしたら良いでしょうか?

【回答】
1.列番号Aをクリック
→セルA1がアクティブでA列が選択された状態
2.メニュー[書式]-[条件付き書式]
3.左のボックスを 数式が に、右のボックスに以下の数式を入力
=LEN(A1)-LEN(SUBSTITUTE(A1,"花",""))=2
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]を選択
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 花が二文字以上入っているセルに色をつけるには以下の数式です。
=LEN(A1)-LEN(SUBSTITUTE(A1,"花",""))>=2

 LEN関数は、文字列内の文字数を返します。

 SUBSTITUTE関数は文字列中の指定された文字を他の文字に置き換えます。
 半角/全角、大文字/小文字が一致してないといけません。
 SUBSTITUTE(文字列, 検索文字列, 置換文字列, 置換対象)という引数をとります。
 置換対象は、文字列に含まれる何番目の検索文字列(今回の場合、花)を置換文字列(今回の場合"")と置き換えるかを指定します。省略した場合は、文字列中のすべての検索文字列が置き換えの対象となります(今回の場合省略しているのですべてが対象となる)。

 (セル内の文字列の文字数)から(セル内に含まれる文字列中の "花" を全て"" に置き換えた文字列の文字数)を引くと(セル内の"花"の文字数)が算出されます。

部分一致4

【問題】
 A列に以下が入力してあります。



花水木
生け花
造花
花より団子
団子
花柄
柄物
花見

花盛り
酒盛り
花札と花束
お札
桜の花と花園と花屋
花屋と花屋

 花屋が二文字入っているセルに色をつけるにはどうしたら良いでしょうか?

【回答】
1.列番号Aをクリック
→セルA1がアクティブでA列が選択された状態
2.メニュー[書式]-[条件付き書式]
3.左のボックスを 数式が に、右のボックスに以下の数式を入力
=(LEN(A1)-LEN(SUBSTITUTE(A1,"花屋","")))/LEN("花屋")=2
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]を選択
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 LEN関数は、文字列内の文字数を返します。

 SUBSTITUTE関数は文字列中の指定された文字を他の文字に置き換えます。
 半角/全角、大文字/小文字が一致してないといけません。
 SUBSTITUTE(文字列, 検索文字列, 置換文字列, 置換対象)という引数をとります。
 置換対象は、文字列に含まれる何番目の検索文字列(今回の場合、花)を置換文字列(今回の場合"")と置き換えるかを指定します。省略した場合は、文字列中のすべての検索文字列が置き換えの対象となります(今回の場合省略しているのですべてが対象となる)。

 (セル内の文字列の文字数)から(セル内に含まれる文字列中の "花屋" を全て "" に置き換えた文字列の文字数)を引くと(セル内の"花屋"の文字数)が算出されます。その結果を("花屋"の文字数")で割ることで、(セル内に"花屋"が何個あるか)が算出されます。

部分一致5

【問題】
 A列に以下が入力してあります。



花水木
生け花
造花
花より団子
団子
花柄
柄物
花見

花盛り
酒盛り
花札と花束
お札
桜の花と花園と花屋
花屋と花屋

 花柄、花見のように先頭の文字が 花 で、文字数が二文字のセルに色をつけるにはどうしたら良いでしょうか?

 造花のように末尾の文字が 花 で、文字数が二文字のセルに色をつけるにはどうしたら良いでしょうか?

【回答】
1.列番号Aをクリック
→セルA1がアクティブでA列が選択された状態
2.メニュー[書式]-[条件付き書式]
3.左のボックスを 数式が に、右のボックスに =COUNTIF(A1,"花?") と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]を選択
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 ワイルドカード文字 ? は、同じ位置にある一文字を意味します。

 末尾の文字が 花 で、文字数が二文字のセルに色をつけるには以下の数式です。
=COUNTIF(A1,"?花")

直前に入力した行全体に色をつける

【問題】
 直前に入力した行全体に色をつけるにはどうしたら良いでしょうか?
 つまり、セルA2に入力したら2行目が、セルC3に入力したら3行目に色をつけたいのです。

【回答】
1.全セルを選択
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =ROW(A1)=CELL("row") と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。
 条件付き書式は、Excel97 から追加された機能です。

 直前に入力した行に色がつきます。また、F9キーを押せばアクティブセルのある行に色がつきます。

 CELL(検査の種類, 対象範囲) という引数をとります。
 CELL関数は、対象範囲の左上隅にあるセルの書式、位置、内容についての情報を返します。
 検査の種類に"row"を指定すると、 対象範囲の左上隅にあるセルの行番号を返します。
 対象範囲で情報が必要なセルを指定します。1つのセルではなく、セル範囲を指定すると、セル範囲の左上隅にあるセルの情報が返されます。省略すると、検査の種類に指定した情報が、最後に変更したセルに返されます。今回の式では、対象範囲を省略しています。

 つまり、それぞれのセルの行番号(=ROW(A1))と最後に変更したセルの行番号(=CELL("row"))が一致しているかどうかが、条件付き書式の条件になっているわけです。

 横に長い表に入力する際には、ウインドウ枠の固定をすると、どの項目の入力をしているのかがわかりやすくなります。ウィンドウ枠の固定をしてもわかりにくい場合には、今回の技が役に立つのではないでしょうか?

土日祝日に色をつける

【問題】

 A列に一ヶ月分の日付が入力されています。
 土日祝日のセルに色をつけるにはどうしたら良いでしょうか?

【回答】
 シート「祝日」とシート「カレンダー」を用意します。

 シート「祝日」で以下の作業をします。

1.セルA1に =カレンダー!A1 と入力

2.A2:A16に以下を入力

=DATE(A1,1,1)
=DATE(A1,1,14-WEEKDAY(DATE(A1,1,0),3))
=DATE(A1,2,11)
=DATE(A1,3,INT(20.8431+0.242194*(A1-1980)-INT((A1-1980)/4)))
=DATE(A1,4,29)
=DATE(A1,5,3)
=DATE(A1,5,5)
=DATE(A1,7,20)
=DATE(A1,9,15)
=DATE(A1,9,INT(23.2488+0.242194*(A1-1980)-INT((A1-1980)/4)))
=DATE(A1,10,14-WEEKDAY(DATE(A1,10,0),3))
=DATE(A1,11,3)
=DATE(A1,11,23)
=DATE(A1,12,23)
=IF(WEEKDAY(DATE(A1,5,3),3)>=5,"−",DATE(A1,5,4))

3.B2:B16に以下を入力

元旦
成人の日
建国記念の日
春分の日
みどりの日
憲法記念日
こどもの日
海の日
敬老の日
秋分の日
体育の日
文化の日
勤労感謝の日
天皇誕生日
国民の休日

4.セルA17に以下の式を入力してセルA30までコピー
=IF(WEEKDAY(A2)=1,A2+1,"−")

5.セルB17に以下の式を入力してセルB30までコピー
=IF(A17="−","−","振替休日")

6.A2:A30を選択して、Ctrl+Shift+#
→日付の表示形式に
7.A2:A30を選択して、名前ボックスに HOLIDAY と入力してEnter

 シート「カレンダー」で

1.セルA1に年を、セルB1に月を入力します。
2.セルA3に =DATE(A1,B1,1) を入力
3.セルA4に =A3+1 を入力し、セルA30までコピー
4.セルA31に
=IF(MONTH(DATE($A$1,$B$1,ROWS($A$3:A31)))=$B$1,DATE($A$1,$B$1,ROWS($A$3:A31)),"")
を入力し、セルA33までコピー
5.A3:A33を選択してCtrl+1 (メニュー[書式]-[セル])
6.[表示形式]タブで[ユーザー定義]を選択、[種類]に yyyy/mm/dd(aaa) と入力してEnter

 シート「カレンダー」で、続いて条件付き書式設定です。

1.A3:A33を選択
→セルA3がアクティブでA3:A33を選択している状態に
2.メニュー[書式]-[条件付き書式]
3.[数式が]で、右のボックスに =OR(WEEKDAY(A3,3)>=5,COUNTIF(HOLIDAY,A3)) と入力
4.[書式]ボタンをクリック
→[セルの書式設定]ダイアログボックスを表示
5.[パターン]タブで[黄]をクリック
6.[OK]ボタンをクリック
7.[OK]ボタンをクリック

【解説】
 サンプルファイルはこちらです。


 [数式が]に
=OR(WEEKDAY(A3,3)>=5,ISNUMBER(MATCH(A3,HOLIDAY,0)))
でも同じ結果になります。

 以下はご参考まで。

○「国民の祝日に関する法律」第2条からの抜粋

元日 一月一日
 年の始めを祝う。
成人の日 一月の第二月曜日
 おとなになつたことを自覚し、みずから生き抜こうとする青年を祝いはげます。
建国記念の日 二月十一日
 建国をしのび、国を愛する心を養う。
春分の日 春分日
 自然をたたえ、生物をいつくしむ。
みどりの日 四月二十九日
 自然に親しむとともにその恩恵に感謝し、豊かな心をはぐくむ。
憲法記念日 五月三日
 日本国憲法の施行を記念し、国の成長を期する。
こどもの日 五月五日
 こどもの人格を重んじ、こどもの幸福をはかるとともに、母に感謝する。
海の日 七月二十日
 海の恩恵に感謝するとともに、海洋国日本の繁栄を願う。
敬老の日 九月十五日
 多年にわたり社会につくしてきた老人を敬愛し、長寿を祝う。
秋分の日 秋分日
 祖先をうやまい、なくなつた人々をしのぶ。
体育の日 十月の第二月曜日
 スポーツにしたしみ、健康な心身をつちかう。
文化の日 十一月三日
 自由と平和を愛し、文化をすすめる。
勤労感謝の日 十一月二十三日
 勤労をたつとび、生産を祝い、国民たがいに感謝しあう。
天皇誕生日 十二月二十三日
 天皇の誕生日を祝う。

○「国民の祝日に関する法律」第三条(休日)

1 「国民の祝日」は、休日とする。
2 「国民の祝日」が日曜日にあたるときは、その翌日を休日とする。
3 その前日及び翌日が「国民の祝日」である日(日曜日にあたる日及び前項に規定する休日にあたる日を除く。)は、休日とする。

○春分日・秋分日については、毎年変わるので、前年の2月1日付けの官報で日本国政府から発表されることになっている。春分日は3月19日と21日の間。秋分日は、9月22日から24日の間で変化するらしい。上記の計算式は簡易計算法で1980年から2099年に適用されるとのこと。

ロックされていないセルに色をつける

【問題】
 ロックされていないセルに色をつけるにはどうしたら良いでしょうか?

【回答】
1.Ctrl+A(または[全セル選択]ボタンをクリック)
→セルA1がアクティブで全セルが選択された状態
2.メニュー[書式]-[条件付き書式]
3.左のボックスを[数式が]に、右のボックスに =CELL("protect",A1)=0 と入力
4.[書式]ボタンをクリック
5.[パターン]タブで好きな色を選択
6.Enter
7.[OK]ボタンをクリック

 ロックされているセルに色をつけるには、上記3.で =CELL("protect",A1)=1を入力します。

【解説】
 条件付き書式は、Excel97 から追加された機能です。

 シートを保護している状態では条件付き書式設定はできません。シート保護を解除してから上記手順を実行します。

 関連ページは以下です。(英語です)

XL2000: Unlocked Cells Not Underlined with Protection Enabled

本日の日の列に色をつける

【問題】
 一行目(A1:AE1)に日付が入っています。

12/1 12/2 ・・・12/30 12/31

 本日の日の列に色をつけるにはどうしたら良いでしょうか?

【回答】
1.[全セル選択]ボタンをクリック
→セルA1がアクティブで全セルを選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =A$1=TODAY() と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。

 条件付き書式設定を行う時のアクティブセルと数式が対応していることがポイントです。

 =A$1=TODAY() と行だけ絶対参照にしています。こうすることで、例えば、セルA5だと =A$1=TODAY() 、セルB3だと =B$1=TODAY() というようにその列の一行目の日付と今日の日付が同じかどうかを判定する式になっています。

同じ列の値がかわったら罫線を引く

【問題】
 C列の値を比較して、変わったところに、罫線をA列からS列まで引きたい。

A列 B列 C列 ........... S列
あああ
あああ
いいい
ううう
ううう
ううう

 上記の例だと、2行目、3行目、6行目に下罫線をひきたいのです。

【回答】
1.A:S列を選択
→セルA1がアクティブでA:S列を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして右のボックスに =$C1<>$C2 と入力
4.[書式ボタン]をクリック
5.[罫線]タブで[下罫線]を選択
6.[OK]ボタンをクリック
7.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。

 =$C1<>$C2 と列だけ絶対参照にしています。こうすることで、例えば、セルA5だと =$C5<>$C6 、セルB3だと =$C3<>$C4 というようにその行のC列とその下の行のC列が同じかどうかを判定する式になっています。

特定範囲のデータを見えなくする

【問題】
 A2:A10に何か入力されているとして、これを見えないようにする/見えるようにする、切り替えを簡単に行うにはどうしたら良いでしょうか?

【回答】
1.A2:A10を選択
2.メニュー[書式]-[条件付き書式]
3.左のボックスを[数式が]に、右のボックスに =COUNTA($C$1) と入力
4.[書式]ボタンをクリック
5.[フォント]タブの[色]のところで[白]をクリック
6.[OK]ボタンをクリック

 これで、セルC1になにか入力(例えば、スペースなど)するとA1:A10のフォントが白になって、消えたように見えます。
 セルC1でDeleteキーを押すと、A2:A10のデータが見れるようになります。

【解説】
 条件付き書式は、Excel97 から追加された機能です。

 セルに色がついている場合には、フォントをその色に合わせる必要があります。

最大値のセルに色をつける

【問題】
 A列の最大値のセルに色をつけるにはどうしたら良いでしょうか?

【回答】
1.列番号Aをクリック
2.メニュー[書式]-[条件付き書式]
3.[セルの値が]で、右のボックスを[次の値に等しい]に、その右のボックスに
=MAX($A:$A) と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.[OK]ボタンをクリック
7.[OK]ボタンをクリック

【解説】
 条件付き書式は、Excel97 から追加された機能です。

 A2:A10内で最大値のセルに色をつけるには以下の手順です。

1.A2:A10を選択
2.メニュー[書式]-[条件付き書式]
3.[セルの値が]で、右のボックスを[次の値に等しい]に、その右のボックスに
=MAX($A$2:$A$10) と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.[OK]ボタンをクリック
7.[OK]ボタンをクリック

各列で最大値のセルに色を付ける

【問題】

 A2:C10の内、各列の最大値のセルにそれぞれ色を付けるには、どうしたら良いでしょうか?

【回答】

1.A2:A10を選択
2.メニュー[書式]-[条件付き書式]
3.[セルの値が]で、[次の値に等しい]を選択し、右のボックスに =MAX(A$2:A$10) と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.[OK]ボタンをクリック
7.[OK]ボタンをクリック

【解説】

 条件付き書式は、EXCEL97以降の機能です。

 =MAX(A$2:A$10) のように行だけ絶対参照にすることで、それぞれの列で最大値のセルに色を付けることができます。

 B2:B10内のセルを選択して、メニュー[書式]-[条件付き書式設定]とすると、数式が、 =MAX(B$2:B$10) になっています。

上位3位までのセルに色を付ける

【問題】

 A2:A10に生徒の名前が、B2:B10に試験の結果が入っています。
 試験の結果が上位3位までの生徒の名前が入っているセル(A列)に色を付けるにはどうしたら良いでしょうか?

【回答】

1.A2:A10を選択
→セルA2がアクティブでA2:A10を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =RANK(B2,$B$2:$B$10)<=3 と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】

 条件付き書式は、EXCEL97以降の機能です。

 試験の結果が上位3位までの試験の結果が入っているセルに色を付けるには、以下の手順です。

1.B2:B10を選択
→セルB2がアクティブでB2:B10を選択している状態
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =RANK(B2,B$2:B$10)<=3 と入力
4.[書式]ボタンをクリック
5.[パターン]タブで[黄]をクリック
6.Enter
7.[OK]ボタンをクリック

 =RANK(B2,B$2:B$10)<=3 と行だけ絶対参照にしておくことで、例えばC2:C10に別の試験の結果を入力した場合に、以下の手順で条件付書式設定をコピーすることができます。

1.セルB2をコピー
2.C2:C10を選択
3.メニュー[編集]-[形式を選択して貼り付け]
4.[書式]にチェック
5.Enter

BINGOの発生数字に色を付ける

【問題】

 BINGOで、既に出た数字に色を付けるには、どうしたら良いでしょうか?
 A1:E6にBingoの表(数字が入ってます)が、入力されています。
 G1:K5に順次発生する数字を入力します。

【回答】

1.A1:E6を選択
→セルA1がアクティブセルでA1:E6を選択
2.メニュー[書式]-[条件付き書式]
3.[数式が]にして、右のボックスに =COUNTIF($G$1:$K$5,A1) と入力
4.[書式]ボタンをクリック
5.[パターン]タブで好きな色をクリック
6.Enter
7.[OK]ボタンをクリック

【解説】

 条件付き書式は、EXCEL97以降の機能です。

数式の入っているセルに色を付ける

【問題】

 シート内で数式の入っているセルの色に色を付けるには、どうしたら良いでしょうか?

【回答】

1.セルA1を選択
2.Ctrl+F3(メニュー[挿入]-[名前]-[定義])
3.[名前]を ISFORMULA に
4.参照範囲に =GET.CELL(48,!A1) と入力
5.Enter

6.[全セル選択]ボタンをクリック
7.メニュー[書式]-[条件付き書式]
8.[数式が]で右のボックスをクリックしてF3キー
9.ISFORMULA
10.Enter
11.[書式]ボタンをクリック
12.[パターン]タブで 黄 をクリック
13.Enter
14.[OK]ボタンをクリック

【解説】

 名前定義で4.0マクロ関数を利用することができます。


Yahoo!ブックマークに登録
エクセル(Excel)技道場 HOME | このページのトップ
Google
ウェブ全体から検索 【エクセル技道場】内を検索