エクセル技道場 HOME |
エクセルの技 目次 |
シート |
関数 |
名前定義 |
ツールバー |
セル選択 |
ファイル |
条件付き書式 |
書式設定 |
編集 |
印刷 |
入力規則 |
マクロ |
グラフ |
ピボットテーブル |
エクセル・ショートカット |
エクセル関数語源リスト |
エクセル関数引数リスト |
【問題】
セルA1に 2000/12/6 と入力したら、
2000/12/06(水)
というふうに表示させるには、どうしたら良いでしょうか?
また、以下のように表示させるには、それぞれどうしたら良いでしょうか?
2000/12/06(水曜日)
2000/12/06(Wed)
2000/12/06(Wednesday)
【回答】
1.セルA1を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に以下のどれかを入力
yyyy/mm/dd(aaa)
yyyy/mm/dd(aaaa)
yyyy/mm/dd(ddd)
yyyy/mm/dd(dddd)
5.Enter
それぞれ以下のように表示されます。
2000/12/06(水)
2000/12/06(水曜日)
2000/12/06(Wed)
2000/12/06(Wednesday)
【解説】
曜日の表示形式は以下の通りです。
aaa :日 月 火 水 木 金 土
aaaa :日曜日 月曜日 火曜日 水曜日 木曜日
金曜日 土曜日
ddd :Sun Mon Tue Wed Thu Fri Sat
dddd :Sunday Monday Tuesday Wednesday Thursday
Friday Saturday
もちろん、2000/12/6 と入力し、[種類]に
aaaa と入力すれば、 水曜日 と曜日だけが表示されます。
【問題】
セルに1234567といった数値が入っています。
これを1,234,567といったように桁区切りを入れるショートカットキーはなんでしょうか?
【回答】
Ctrl+Shift+!
【解説】
1,234,567 とあらかじめ桁区切りをつけて入力すると、桁区切りの表示になります。
[書式設定]ツールバーの[桁区切りスタイル]ボタンをクリックでもセルの表示形式を桁区切りにすることができます。
Ctrl+Shift+! と[桁区切りスタイル]ボタンでは、同じ桁区切りでも以下のように、若干違いがあります。
・マイナス数値について、Ctrl+Shift+!では黒字で表示される。一方、[桁区切りスタイル]ボタンでは赤字で表示される。
・0未満-0.5超の数値について、Ctrl+Shift+!では、0
と表示される。一方、[桁区切りスタイル]ボタンでは赤字で
-0 と表示される。
この違いの原因は、Ctrl+Shift+!の方は #,##0
と表示形式が定義されているのに対して、[桁区切りスタイル]ボタンの方は
#,##0;[赤]-#,##0 と定義されることにあります。
表示形式は三つまでの数値の書式と、文字列用に四つ目の書式を持つことができます。
各書式は次のようにセミコロン(;)で区切って指定します。
<正数>;<負数>;<ゼロ>;<文字列>
二つのセクションだけを指定した場合、最初のセクションは正数とゼロの表示形式になり、二番目のセクションは負数の表示形式になります。
<正数及びゼロ>;<負数>
一つのセクションだけを指定した場合は、その表示形式がすべての数値に適用されます。
<正数、負数及びゼロ>
【問題】
セルに1,234,567といった数値が入っています。
これを 1,235 と千単位で表示するにはどうしたら良いでしょうか?
また、百万単位で表示するにはどうしたら良いでしょうか?
【回答】
1.範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に #,##0,;-#,##0, と入力
5.Enter
【解説】
百の位で四捨五入した値で表示されます。
4.のところで、 #,##0, だけでも良いのですが、セルに-100などが入っていた場合、
0 と表示されます。回答のように設定すると、
-0 とマイナス記号がつきます。
百万単位で表示するには上記4.のところで以下を入力します。10万の位で四捨五入された値で表示されます。
#,##0,,;-#,##0,,
以下のように入力すると、それぞれ、1,235千、1百万のように表示されます。
#,##0,"千";-#,##0,"千"
#,##0,,"百万";-#,##0,,"百万"
【問題】
セルに1000が入力されていたら1,000と、-1000が入力されていたら△
1,000と、0が入力されていたら − と表示させるにはどうしたら良いでしょうか?
【回答】
1.範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に #,##0;"△ "#,##0;"−"
と入力
5.Enter
【解説】
表示形式は三つまでの数値の書式と、文字列用に四つ目の書式を持つことができます。
各書式は次のようにセミコロン(;)で区切って指定します。
<正数>;<負数>;<ゼロ>;<文字列>
二つのセクションだけを指定した場合、最初のセクションは正数とゼロの表示形式になり、二番目のセクションは負数の表示形式になります。
<正数及びゼロ>;<負数>
一つのセクションだけを指定した場合は、その表示形式がすべての数値に適用されます。
<正数、負数及びゼロ>
【問題】
セルに1000が入力されていたら1,000と、-1000が入力されていたら△
1,000と、0が入力されていたら表示しないようにするにはどうしたら良いでしょうか?
【回答】
1.範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に #,##0;"△ "#,##0; と入力
5.Enter
【解説】
表示形式の三つ目のセクションは、ゼロの表示形式をあらわします。そこに何も入力しなければ、ゼロは表示されません。
表示形式は三つまでの数値の書式と、文字列用に四つ目の書式を持つことができます。
各書式は次のようにセミコロン(;)で区切って指定します。
<正数>;<負数>;<ゼロ>;<文字列>
二つのセクションだけを指定した場合、最初のセクションは正数とゼロの表示形式になり、二番目のセクションは負数の表示形式になります。
<正数及びゼロ>;<負数>
一つのセクションだけを指定した場合は、その表示形式がすべての数値に適用されます。
<正数、負数及びゼロ>
【問題】
セルA1に 12:00 を入力、セルA2に13:00 を入力し、セルA3に =SUM(A1:A2) を入力すると、01:00
と表示されます。これを 25:00 と表示させるには、どうしたら良いでしょうか?
【回答】
1.セルA3を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に [hh]:mm
と入力
5.Enter
【解説】
時、分、秒を表す書式記号は、それぞれ、h、m、sです。
hだと、1、2、3のように一桁の時間の場合、そのまま表示されます。
hhのように重ねると、一桁の時間の場合、01、02、03といった感じであたまにゼロがついて表示されます。
h
0 〜 23 (時)
hh 00 〜 23 (時)
m 0 〜 59 (分)
mm 00 〜 59 (分)
s 0 〜 59
(秒)
ss 00 〜 59 (秒)
24時間、60分、60秒を超える時間を表示させるには、角括弧 ([]) を使用し表示形式を変更します。
[hh]:mm
[hh]
[mm]:ss
[mm]
[ss]
また、"m" または "mm" は、"h" または "hh"
の直後、あるいは "ss" の直前に指定します。これ以外の位置に指定または単独で使用すると、分ではなく月が表示されます。[mm]とすると、分が表示されます。
秒の小数部分を表示するには、以下のようにします。
ss.00
[ss].00
【問題】
001や012のように先頭にゼロをつけて表示させるにはどうしたら良いでしょうか?
【回答】
範囲を選択してから、以下の手順です。
1.Ctrl+1
(メニュー[書式]-[セル])
2.[表示形式]タブの[分類]で ユーザー定義 をクリック、[種類]に 000
と入力
3.Enter
【解説】
上記手順3.の[種類]で必要な桁数分、0を入力します。
あたまにシングルクォーテーション(')をつけて入力する方法もあります。
また、セルの書式をあらかじめ[文字列]に設定しておく方法もあります。範囲を選択してから、[表示形式]タブの[分類]で[文字列]をクリックしてEnterです。
【問題】
ある範囲に何を入力しても”/”が表示されるようにしたいのですが、どうしたら良いでしょうか。
【回答】
1.セル範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に "/";"/";"/";* "/"
と入力
5.Enter
【解説】
これで、数値でも文字でも何か入力すると"/"が表示されるようになります。
表示形式は三つまでの数値の書式と、文字列用に四つ目の書式を持つことができます。
各書式は次のようにセミコロン(;)で区切って指定します。
<正数>;<負数>;<ゼロ>;<文字列>
最後のセクション、すなわち文字列の書式だけ * "/" となっています。
既定の [標準] 表示形式が設定されているセルでは、文字列は左詰めに配置され、数字、日付、および時刻は右詰めに配置されます。
従って、文字列の書式が"/"だけだと数値が右詰に配置されているのに文字列は左詰めに配置されてしまいます。
表示形式でアスタリスク(*)を用いると、アスタリスク(*)の直後の文字をセル幅に達するまで繰り返し表示します。
この場合は、アスタリスク(*)の後にスペースが入っているので、スペースをセル幅に達するまで繰り返し表示します。その結果、文字列が入力されても右詰めに表示されることになるわけです。
【問題】
セルの中に、例えば100%と表記して、後で%の表記を止めたいと思って削除しましたが、再度数字を100と入れると%が表記されます。
これをどうしたら削除できるのでしょうか。普通に100だけ入れるには、どうすればいいでしょうか。
【回答】
表示形式がパーセントになっているので、これを標準に戻します。
1.セルを選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を 標準 に
4.Enter
表示形式を標準にするショートカットキーは、 Ctrl+Shift+^
です。
【解説】
表示形式をパーセントから標準に戻すと、100%は1と表示されるようになります。
もし、これを100としたい場合には、以下の手順です。
1.どこか未入力のセルに
100 を入力
2.Ctrl+C
(コピー)
3.100倍にしたいセル範囲を選択
4.メニュー[編集]-[形式を選択して貼り付け]
5.[値]と[乗算]にチェック
6.Enter
7.手順1.で100を入力したセルを選択してDelete
【問題】
分数を入力したいのですが、例えば 1/2 と入力すると日付に変換されてしまいます。
分数として入力するにはどうしたら良いでしょうか?
【回答】
0
1/2 といった感じで0とスペースの後に入力します。
【解説】
1 1/2 などは、そのまま 1 1/2
と入力すれば分数として入力されます。
つまり、以下のように入力すると分数として入力されます。
整数部分 スペース
分子/分母
セルには分数として表示されますが、数式バーには分数の実際の値が表示されます。
以下のような方法でも 1/2 と表示させることができます。しかし、これらの方法では数値ではなく文字列として入力されます。
・あたまにシングルクォーテーション(')をつける('1/2)
・あたまにスペースをつける
・表示形式をあらかじめ文字列にしておく
【問題】
セルに文字列や数値が入力された時、パスワードを入力した時のように***と表示させるにはどうしたら良いでしょうか?
【回答】
1.セル範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に **;**;**;**
と入力
5.Enter
【解説】
表示形式でアスタリスク(*)を用いると、アスタリスクの直後の文字をセル幅に達するまで繰り返し表示します。
この場合は、アスタリスクの後にアスタリスクが入っているので、アスタリスクをセル幅に達するまで繰り返し表示します。
これで、セルに何が入力されてもセル幅いっぱいにアスタリスク(*)が表示されます。
[種類]を以下のようにすると、セルに何が入力されても *** が右詰めで表示されます。
"***";"***";"***";* "***"
【問題】
123-4567
111-2222
333-5555
のように郵便番号を入力しました。
入力後、〒
を郵便番号の頭につけなければならなくなりました。
〒123-4567
〒111-2222
〒333-5555
どうすれば良いでしょうか?
【回答】
1.〒
をつける範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.種類に "〒"@
と入力
5.Enter
【解説】
〒
マークはゆうびんを変換して出します。
文字列ではなく、数値として入力しておいて、表示形式の[分類]で その他[種類]で
郵便番号 として、ハイフンを入れるというやり方もあります。
これに頭に 〒 をつけるには、[分類] をユーザー設定 にして、[種類]を以下のようにします。
[<=999]"〒"000;[<=99999]"〒"000-00;"〒"000-0000
【問題】
セルに全角の数字を入力すると自動的に半角に変更になります。
全角のままで表示させるにはどうしたらよいでしょうか。
【回答】
1.数値を入力する範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に [DBNum3]0
と入力
5.Enter
【解説】
セルに 1234567890 が入力されている時に、表示形式の[種類]を変えた場合の表示例は以下です。
[DBNum1]0
一二三四五六七八九〇
[DBNum2]0 壱弐参四伍六七八九〇
[DBNum3]0
1234567890
[DBNum1]G/標準 十二億三千四百五十六万七千八百九十
[DBNum2]G/標準 壱拾弐億参阡四百伍拾六萬七阡八百九拾
[DBNum3]G/標準 十2億3千4百5十6万7千8百9十
' をあたまにつけて全角の数字を入力する、表示形式を文字列にあらかじめしておく、といった方法もあります。
【問題】
以下のようなデータがあります。
13.5
16.85
135.2
1.25
このデータを下記の様に小数点位置を揃えて表示させるには、どうしたら良いでしょうか?
13.5
16.85
135.2
1.25
【回答】
1.セル範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]で ユーザー定義 を選択
4.[種類]に #,##0.0?
と入力
5.Enter
【解説】
これで、
13.5
16.85
135.2
1.25
と表示されます。
表示形式で ?
を指定すると、余分なゼロがスペースで表示されます。
整数が入力されている場合には、1.0などのように表示されます。
【問題】
表示形式を日付に設定するショートカットキーは何でしょうか?
【回答】
Ctrl+Shift+#
【解説】
以下の手順でもできます。
1.Ctrl+1
(メニュー[書式]-[セル])
2.[表示形式]タブの[分類]を 日付 に
3.[種類]を 1997/3/4 に
4.Enter
【問題】
セルに全角の数字を入力すると自動的に半角に変更になります。
全角かつ桁区切りで表示させるにはどうしたらよいでしょうか。
例えば、1234
を入力したら、1,234 のように表示させたいのです。
【回答】
1.数値を入力する範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に [DBNum3]#,##0
と入力
5.Enter
【解説】
セルに 1234567890 が入力されている時に、表示形式の[種類]を変えた場合の表示例は以下です。
[DBNum1]#,##0
一,二三四,五六七,八九〇
[DBNum2]#,##0 壱,弐参四,伍六七,八九〇
[DBNum3]#,##0 1,234,567,890
【問題】
例えばセルに 1 と入力したときに ○ と表示させたい。条件が2つまでなら(例えば
1 のとき ○ 、 2 のとき × など)書式設定のユーザー定義で設定できることがわかったのですが、表示させたい条件が4つあるのです。
【回答】
1.セル範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.種類に [=1]"○";[=2]"×";"△";* "□"
と入力
5.Enter
これで1なら○が、2なら×が、それ以外の数値なら△が、文字列なら□が表示されます。
【解説】
"○";"×";"△";*
"□"
にすると、 正数なら○が、負数なら×が、ゼロなら△が、文字列なら□が表示されます。
表示形式は三つまでの数値の書式と、文字列用に四つ目の書式を持つことができます。
各書式は次のようにセミコロン(;)で区切って指定します。
<正数>;<負数>;<ゼロ>;<文字列>
最後のセクション、すなわち文字列の書式だけ * "□" となっています。
既定の [標準] 表示形式が設定されているセルでは、文字列は左詰めに配置され、数字、日付、および時刻は右詰めに配置されます。
従って、文字列の書式が"□"だけだと数値が右詰に配置されているのに文字列は左詰めに配置されてしまいます。
表示形式でアスタリスク(*)を用いると、アスタリスク(*)の直後の文字をセル幅に達するまで繰り返し表示します。
この場合は、アスタリスク(*)の後にスペースが入っているので、スペースをセル幅に達するまで繰り返し表示します。その結果、文字列が入力されても右詰めに表示されることになるわけです。
【問題】
セルに文字列が入力された時点で、その文字列の前後に( )を表示したいのですが、どうすれば良いでしょうか?
例えば、test と入力したら、(test)
と表示させたいのです。
【回答】
1.文字を入力する範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.種類に (@) と入力
5.Enter
【解説】
これで、例えばセルに test と入力すると、 (test)
と表示されます。
入力した文字列を表示する部分に @ 記号を指定します。文字列の書式部分に
@ 記号がない場合、入力した文字列は表示されません。
入力した文字列と共に特定の文字列を表示する場合は、表示する文字列をダブル
クォーテーションで囲みます。
ただし、スペース、$、-、+、/、(、)、:、!、^、&、`(アクセント記号)、'
(クォーテーション) 、~、{、}、=、<、および > を入力する場合、ダブル
クォーテーションを付ける必要はありません。
【問題】
セルの書式設定で、表示形式から日付を指定出来ますが、半角で表示されます。これを全角で表示するには、どうすれば良いでしょうか。
例えば、1月1日ではなく、1月1日と表示させたいのです。
【回答】
1.日付を入力する範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.種類に [DBNum3]m"月"d"日"
と入力
5.Enter
【解説】
セルに 2001/12/12 が入力されている時に、表示形式の[種類]を変えた場合の表示例は以下です。
[DBNum1]m"月"d"日"
十二月十二日
[DBNum2]m"月"d"日" 壱拾弐月壱拾弐日
[DBNum3]m"月"d"日" 12月12日
【問題】
10の5乗と書くときに10の右上に小さい5を書くにはどうすればいいのでしょうか?
【回答】
1.セルを選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]で 文字列 を選択
4.Enter
5.105
と入力
6.F2キーで編集モードにして 5 の部分を選択
7.Ctrl+1
(メニュー[書式]-[セル])
8.[上付き]にチェック
9.Enter
10.Enter
【解説】
数値の一部に書式設定することはできないので、文字列にしてからセル内の一部の書式を変更しています。
10の5乗を計算するには、
=10^5
または、
=POWER(10,5)
といった数式を使います。
【問題】
日付を入力したセルを平成13年7月1日のように表示させているのですが、これを、H13
というような書式にするにはどうしたら良いでしょうか?
【回答】
1.範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に ge
と入力
5.Enter
【解説】
[種類]を gee とすると、例えば 1995/1/1 をセルに入力すると、 H07 のように表示されます。ge
の場合には、 H7 と0なしで表示されます。
また、[種類]を gge とすると 平13 のように表示されます。[種類]を ggge
とすると 平成13 のように表示されます。
【問題】
数値をプラス/マイナスにかかわらずカッコつきで表示するには、どうしたら良いでしょうか?
また、カッコは、以下のようにセルの両端につけたいのです。
(
12345)
( 123)
( -123)
【回答】
1.範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に (* G/標準);(* -G/標準)
と入力
5.Enter
【解説】
表示形式でアスタリスク(*)を用いると、アスタリスク(*)の直後の文字をセル幅に達するまで繰り返し表示します。
この場合は、アスタリスク(*)の後にスペースが入っているので、スペースをセル幅に達するまで繰り返し表示します。その結果、
( が左端に表示されることになるわけです。
【問題】
セルの高さや幅を変えたとき、その行あるいは列のセルが全てその大きさに変わってしまいます。
ひとつのセルの高さあるいは幅だけ(例えばセルA1だけとか)を変えることは可能なのでしょうか?
【回答】
セルを結合します。
1.A1:B2を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[配置]タブで[セルを結合する]にチェック
4.Enter
【解説】
セルを結合することで、体裁が良くなることもありますが、並べ替えができないなど、不都合な点もいくつかあるので注意が必要です。
【問題】
為替レートを入力しています。
123.15
122.42
121.1
122.28
122
これを、必ず小数点第2位まで表示させるにはどうしたら良いでしょうか?
123.15
122.42
121.10
122.28
122.00
【回答】
1.範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を 数値 に
4.[小数点以下の桁数]を2に
5.Enter
【解説】
範囲を選択してから、[書式設定]ツールバーの[小数点表示桁上げ]ボタンをクリックする方法もあります。この場合、アクティブセルの小数点以下の桁数を基準に桁上げされます。
【問題】
日付を入力した時に25-Janではなく、25-JANと全て大文字で表示させたいのですが、どうすれば良いでしょうか?
【回答】
別のセルになりますが、以下の数式でいかがでしょうか?
=UPPER(TEXT(A1,"d-mmm"))
【解説】
月の表示形式は以下があります。
M 1
〜 12 (月)
Mm 01 〜 12 (月)
Mmm Jan 〜 Dec (月)
Mmmm January 〜 December
(月)
Mmmmm J 〜 D (月名の最初の文字)
【問題】
セル内に数値を入力すると、自動的に「○人」と表示するようにするにはどうしたら良いでしょうか?、
例えば、
10 と入力したら、 10人 と表示させたいのです。
【回答】
1.範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に 0"人"
と入力
5.Enter
【解説】
1000と入力した時に1,000人のように桁区切りをつけるようにするには、上記4の[種類]を
#,##0"人" とします。
【問題】
作成した名簿のすべての名前の最後に”様”をつけるにはどうしたら良いでしょうか?
【回答】
1.範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に @"様"
と入力
5.Enter
【解説】
文字列を表示させる部分に @(アットマーク)記号を指定します。
【問題】
数値を入力して正数の場合には + を、負数の場合には − をあたまにつけ、0の場合には、
±0 とするにはどうしたら良いでしょうか?
1 → +1
-1 → -1
0 →
±0
【回答】
+G/標準;-G/標準;"±"0
【解説】
1000と入力した時に+1,000のように桁区切りをつけるようにするには、上記4の[種類]を
+#,##0;-#,##0;"±"0 とします。
【問題】
セルに数値を入力すると、
|
123|
のようにセルの右端にぴったりくっついて表示されます。
見にくい場合があるので、
| 123
|
のように右に一桁分スペースをあけて表示させるには、どうすれば良いでしょうか?
【回答】
1.セル範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]で 数値 を選択
4.[負の数]の表示形式で -1234
を選択
5.Enter
【解説】
この書式設定を行った後で、[分類]を ユーザー定義 にしてみると[種類]のところは
0_ のように _(アンダーバー)の後に半角スペースとなっています。
_(アンダーバー)は、 _ の後に続く文字幅分スペースを表示させる書式記号です。
なお、[表示形式]タブの[分類]で 数値 を選択した後、[小数点以下の桁数]の指定や[桁区切り(,)を使用する]ことも可能です。
【問題】
日付の表示が突然おかしくなりました。
1997/3/4
と表示されるはずなのに
1997 3 4 のように / が表示されなくなりました。
どうすればちゃんと 1997/3/4
のように表示されるようになるでしょうか?
【回答】
[スタート]-[設定]-[コントロールパネル]-[地域]の[地域]タブで 日本語 になっているかどうか確認してみてください。
また、[地域]の[日付]タブの[区切り記号]が / になっているかどうかも確認してみてください。
【解説】
エクセル自身のトラブルではありませんが、エクセル関係の掲示板で、わりと聞かれる質問です。
たいていは、[地域]タブで 日本語 以外が選択されていることが原因のようです。
日本語 以外が選択されていると、数値の表示が 123,456.0 ではなく、123.456,0
のように表示される場合もあります。
【問題】
数値を入力して、[書式]ツールバーの[通貨]ボタンを押すと、以下のように表示されます。
\10
\100
\1,000
これを以下のように\マークを左端に揃えて表示させるにはどうしたら良いでしょうか?
\
10
\ 100
\1,000
【回答】
1.範囲を選択
2.Ctrl+1
(メニュー[書式]-[セル])
3.[表示形式]タブの[分類]で 会計
を選択
4.Enter
【解説】
上記手順3.で 会計 を選択した後で[分類]で ユーザー定義 を選択すると、[種類]のところが以下のようになっていることがわかります。
_ \* #,##0_ ;_ \* -#,##0_ ;_ \*
"-"_ ;_ @_
; で四つのセクションに分かれており、それぞれのセクションで正の数値、負の数値、ゼロ、文字列の表示形式を定義しています。
* (アスタリスク)は、* の後に続く文字をセル幅がいっぱいになるまで繰り返し表示させる書式記号です。*
の後ろは半角スペースなので、この場合には、半角スペースがセル幅いっぱいになるまで表示されるため、\マークが左でそろっているわけです。
_(アンダーバー)は、 _ の後に続く文字幅分スペースを表示させる書式記号です。_
の後ろは半角スペースなので、この場合には、半角スペースの幅の分だけ \ の前にスペースが追加されているわけです。
【問題】
0
-10
10
上記データを入力後、セルの表示形式を 会計 にしたところ、以下のように表示されました。
\ -
\ -10
\ 10
これを以下のように表示させるにはどうしたら良いでしょうか?
\ 0
-\ 10
\ 10
【回答】
1.範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]で ユーザー定義 を選択
4.[種類]に _-\* #,##0_ ;-\* #,##0_ ;_-\* 0_ ;_ @_ を入力
5.Enter
【解説】
この問題では、以下の条件をクリアすることが求められています。
0を - ではなく0と表示させる
負の数値の場合、\の前に - をもってくる
正、負、ゼロの\マークの位置を揃える
上記手順3.で 会計 を選択した後で[分類]で ユーザー定義 を選択すると、[種類]のところが以下のようになっていることがわかります。
_ \* #,##0_ ;_ \* -#,##0_ ;_ \* "-"_ ;_\@_
上記表示形式の定義を、以下のようにすることで、上記三つの条件をクリアしているわけです。
正、ゼロ、文字列の表示形式の定義の _ のあとのスペースを - に
負の表示形式の定義の変更
ゼロの表示形式の定義の "-" を0に
_(アンダーバー)は、 _ の後に続く文字幅分スペースを表示させる書式記号です。_
の後を半角スペースではなく、 - にすることで正、負、ゼロの\マークの位置を揃えることが可能になります。
セルに日付、例えば、 2001/10/6 を入力し、
1.範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]で ユーザー定義 を選択
4.[種類]に m/d(aaa) を入力
5.Enter
のようにして書式設定をすると、 10/6(土) と表示されます。
これを
10/6
(土)
のように一つのセル内に
一行目は月日
二行目は曜日
と二行で表示させるには、どうすれば良いでしょうか?
【回答】
1.範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]で m/d を入力してから Ctrl+J その後 (aaa) と入力
5.[配置]タブで[折り返して全体を表示]にチェック
6.Enter
7.曜日が表示されるようにセルの高さを調整
【解説】
セル内改行は Alt+Enter ですが、書式設定や置換などで改行を指定するには、Ctrl+J(Ctrlキーを押しながらJキーを押す)とします。
【問題】
計算を、入力、計算、表示ともに度、分、秒でやりたいのですが、どうすれば良いでしょうか?
例えば
30-15-30 + 15-00-30 = 45-16-00
【回答】
1.数値を入力する範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.種類に [h]-mm-ss と入力
5.Enter
【解説】
入力については、30:15:30 のように、時刻の形式で入力します。
45°16′00″ のように表示させたい場合には、上記手順4.で
[h]"°"mm"′"ss"″"
と入力します。
【問題】
セルに1から12の数値を入力、例えば 5 を入力すると 5月 のように表示させ、文字列、0、負数、12を超える数値を入力すると赤色で
----- と表示させるにはどうすれば良いでしょうか?
例;
9 → 9月
テスト → --------
0 → --------
-7 → --------
15 → --------
【回答】
1.範囲を選択
2.Ctrl+1 (メニュー[書式]−[セル])
3.[表示形式]タブの[分類]のところで[ユーザー設定]を選択
4.[種類]のところで [赤][>12]*-;[>=1]0"月";[赤]*-;[赤]*- と入力
5.Enter
【解説】
上記手順4の[種類]のところで [>12] ;[>=1]0"月";; と入力すると、文字列、0、負数、13などを入力しても表示されなくなります。
【問題】
セルに DEC2000 と入力すると、 Dec-00 と表示されます。数式バーを見てみると、2000/12/1
となっており日付として認識されてしまったようです。
文字列として、 DEC2000 を入力するにはどうすれば良いでしょうか?
【回答】
範囲を選択してから、以下の手順です。
1.Ctrl+1 (メニュー[書式]-[セル])
2.[表示形式]タブの[分類]で 文字列 をクリック
3.Enter
【解説】
あたまにアポストロフィ(')をつけて 'DEC2000 のように入力する方法や、あたまにスペースをつけて入力する方法もあります。
以下のページもご参考になるのでは?
[XL2000]英語の月名と数値を入力した場合の日付認識について
http://support.microsoft.com/default.aspx?scid=kb;ja;180952
【問題】
セルに1,234,567といった数値が入っていて、これを 1,235 と千単位で表示する方法は、
【エクセル技道場】−書式設定−千単位、百万単位で表示
http://www2.odn.ne.jp/excel/waza/format.html#SEC3
でわかりました。
1,234,567
を
1,234.6
のように、千単位かつ小数第1位まで表示させるには、どうしたらよいでしょうか?
【回答】
1.範囲を選択
2.Ctrl+1 (メニュー[書式]-[セル])
3.[表示形式]タブの[分類]を[ユーザー定義]に
4.[種類]に #,##0.0,;-#,##0.0, と入力
5.Enter
【解説】
百万単位かつ小数第1位まで表示させる場合には、
#,##0.0,,;-#,##0.0,,
のようにします。
【問題】
セルの表示形式を「日付」の「平成13年3月14日」にして、1989/1/10を入力すると、平成1年1月10日と表示されます。これを「平成元年1月10日」と表示するにはどうしたらよいでしょうか?
【回答】
平成1年を平成元年とするだけでしたら、書式設定を
[<32516]ggge"年"m"月"d"日";[<32874]"平成元年"m"月"d"日";ggge"年"m"月"d"日"
でいかがでしょうか?
【解説】
大正1年、昭和1年も元年にしたいのでしたら、数式になるかと思います。
=SUBSTITUTE(TEXT(A1,"gggee年m月d日"),"01年","元年")